# Basic persistency

**URL:** <https://swi-prolog.discourse.group/t/basic-persistency/2808>\
**Category:** Useful Code\
**Created:** [August 20, 2020, 7:46pm UTC](https://swi-prolog.discourse.group/t/basic-persistency/2808 "2020-08-20T19:46:35Z")\
**Posts on this page:** 1\
**Page:** 1

<div class="post-metadata">

**Author:** ![EricGT](https://avatars.discourse-cdn.com/v4/letter/e/f1d935/32.png) [@EricGT](https://swi-prolog.discourse.group/u/EricGT)\
**Post date:** [August 20, 2020, 7:46pm UTC](https://swi-prolog.discourse.group/t/basic-persistency/2808/1 "2020-08-20T19:46:36Z")

</div>

This is an example of code using predicate\_property/2 and import\_module/2 to collect facts about modules then using [library(persistency)](https://www.swi-prolog.org/pldoc/man?section=persistency) saves them to a file when the top-level is halted.

```prolog
:- module(module_tools,[
        init/0,
        list_uses/1,
        list_imports/1,
        compare/0
    ]).

:- use_module(library(persistency)).

:- persistent
    uses(super:atom,module:atom),
    imports(module:atom,import:atom).

:- initialization(db_attach('module.journal', [])).

add_uses(Super,Module) :-
    (
        uses(Super,Module), !
    ;
        assert_uses(Super,Module)
    ).

init_uses :-
    forall(
            predicate_property(Super:_, imported_from(Module)),
            add_uses(Super,Module)
        ).

list_uses(uses(Super,Module)) :-
    uses(Super,Module).

add_imports(Module,Import) :-
    (
        imports(Module,Import), !
    ;
        assert_imports(Module,Import)
    ).

init_imports :-
    forall(
            (
                current_module(Module),
                import_module(Module,Import)
            ),
            add_imports(Module,Import)
        ).

list_imports(imports(Module,Import)) :-
    imports(Module,Import).

init :-
    init_uses,
    init_imports.

compare :-
    missing_imports,
    missing_uses.

missing_imports :-
    list_uses(uses(A,B)),
    (
        list_imports(imports(A,B))
    ->
        true
    ;
        format('Missing import: ~w, ~w~n',[A,B])
    ),
    fail.
missing_imports.

missing_uses :-
    list_imports(imports(A,B)),
    (
        list_uses(uses(A,B))
    ->
        true
    ;
        format('Missing uses: ~w, ~w~n',[A,B])
    ),
    fail.
missing_uses.

```

Example usage.

```prolog
Welcome to SWI-Prolog (threaded, 64 bits, version 8.3.5-8-ge14460a94)

?- working_directory(_,'C:/Users/Groot/Documents').
true.

?- ['module tools'].
true.

?- init.
true.

?- list_uses(Uses).
Uses = uses(prolog_source, system) ;
Uses = uses(prolog_source, prolog_operator) ;
Uses = uses(prolog_source, '$expand') ;
...

?- list_imports(Imports).
Imports = imports(prolog_source, system) ;
Imports = imports(swi_option, system) ;
Imports = imports(prolog_operator, system) ;
...

?- compare.
...
Missing import: prolog_metainference, lists
Missing import: prolog_metainference, apply
Missing uses: prolog, user
Missing uses: pce_expansion, user
...

```

For an example of using the data from the persistent file see: [Convert facts to GraphViz dot file using DCGs](https://swi-prolog.discourse.group/t/convert-facts-to-graphviz-dot-file-using-dcgs/2809)

> **Windows notes (click triangle to expalnd**
>
> On Windows since this will create a file and the file might be scanned by antivirus software such as Windows Defender, consider disabling scans of the file or folder.
> 
> Here is an example during a large update with the Antivirus service also loading down the CPU.
> 
> ![image](https://global.discourse-cdn.com/free1/uploads/swiprolog/original/2X/5/52c0e44c58e42d664d561866524420b228ca7ac8.png)
