Format/2,3 special sequence @ example

EricGT · July 30, 2021, 11:37am

Simple example of using special sequence @ with format/2.

@
Interpret the next argument as a goal and execute it. Output written to the current_output stream is inserted at this place. Goal is called in the module calling format/3. This option is not present in the original definition by Quintus, but supported by some other Prolog systems.

File: example.pl

format_example :-
    List = [1,a,'B',3.14,"Hello"],
    format('~@',[print_list(List)]).

print_list([H|T]) :-
    format('   ~k~n',[H]),
    print_list(T).
print_list([]).

Demonstration

Welcome to SWI-Prolog (threaded, 64 bits, version 8.3.27-24-g44c2d0e2d)

?- working_directory(_,'C:/Users/Groot').
true.

?- [example].
true.

?- format_example.
   1
   a
   'B'
   3.14
   "Hello"
true.

Some real world examples:

github.com

SWI-Prolog/packages-chr/blob/6b020f7a523beb73809bf069e40cedd121ded778/chr_compiler_errors.pl#L89-L101


      
          chr_warning(unsupported_pragma(Pragma,Rule),Message,Params) :- !,
          	long_line_with_equality_signs,
          	format(user_error,'CHR compiler WARNING: unsupported pragma ~w in ~@.\n',[Pragma,format_rule(Rule)]),
          	format(user_error,'    `--> ',[]),
          	format(user_error,Message,Params),
                  format(user_error,'    Pragma is ignored!\n',[]),
          	long_line_with_equality_signs.
          chr_warning(problem_pragma(Pragma,Rule),Message,Params) :- !,
          	long_line_with_equality_signs,
          	format(user_error,'CHR compiler WARNING: unsupported pragma ~w in ~@.\n',[Pragma,format_rule(Rule)]),
          	format(user_error,'    `--> ',[]),
          	format(user_error,Message,Params),
          	long_line_with_equality_signs.

github.com

SWI-Prolog/packages-chr/blob/d8fac8bc5ce4cfaee37d87be5204764019114460/chr_translate_bootstrap.pl#L355-L384


      
          check_pragma(Pragma, PragmaRule, N) :-
          	Pragma = unique(_,_),
          	!,
          	format('CHR compiler WARNING: undocumented pragma ~w in ~@.\n',[Pragma,format_rule(PragmaRule,N)]),
          	format('    `--> Only use this pragma if you know what you are doing.\n',[]).
          
          check_pragma(Pragma, PragmaRule, N) :-
          	Pragma = already_in_heads,
          	!,
          	format('CHR compiler WARNING: currently unsupported pragma ~w in ~@.\n',[Pragma,format_rule(PragmaRule,N)]),
          	format('    `--> Pragma is ignored. Termination and correctness may be affected \n',[]).
          
          check_pragma(Pragma, PragmaRule, N) :-
          	Pragma = already_in_head(_),
          	!,
          	format('CHR compiler WARNING: currently unsupported pragma ~w in ~@.\n',[Pragma,format_rule(PragmaRule,N)]),
          	format('    `--> Pragma is ignored. Termination and correctness may be affected \n',[]).
          
          check_pragma(Pragma,PragmaRule,N) :-
          	format('CHR compiler ERROR: invalid pragma ~w in ~@.\n',[Pragma,format_rule(PragmaRule,N)]),

This file has been truncated. show original

github.com

SWI-Prolog/swipl-devel/blob/9cf6502af6fbac5a078dd670f07e1b13905c1263/library/strings.pl#L224-L226


      
          exec_interpolate1(_Map, goal(Goal), Out) :-
              !,
              format(string(Out), '~@', [Goal]).

github.com

SWI-Prolog/swipl-devel/blob/9cf6502af6fbac5a078dd670f07e1b13905c1263/src/Tests/core/test_format.pl#L53-L56


      
          test(fail, fail) :-
          	format('~@', [fail]).
          test(fail, throws(error(42))) :-
          	format('~@', [throw(error(42))]).

Topic		Replies	Views
Careful with format/2 General	12	578	January 17, 2023
Surprising result with equals dot dot Help! functor	16	1171	February 8, 2022
Confusing behavior of sequence//3 and sequence//5 from dcg/high_order Help! how-to	18	1273	December 25, 2020
Best practices for printing Nice to know best_practices , printing	4	2564	January 12, 2023
Can I make Prolog's "format/x" family behave leniently? Split Topic	9	1424	January 26, 2020

Format/2,3 special sequence @ example

Related Topics