Wrap predicate example by GPT

General
5

Here is working code for wrap_predicate/4 created in the spirit of the what the GPT generated.

Rember that when working with wrappers, if a wrapper that should be removed was not then you may get unexpected results when using the wrapped predicate. Often during development for such cases killing the top level and starting over is the fastest way to remove the wrapper.

File: some_module.pl

:- module('some_module',
    [check/1]
).

% Demonstrate basic usage of sum/3 with two negative numbers.
% Result:
%    Sum of -1 and -5 is -6
%    true.
check(01) :-
    X = -1,
    Y = -5,
    add(X,Y,Sum),
    format('Sum of ~d and ~d is ~d~n',[X,Y,Sum]).

% Demonstrate basic usage of positive_numbers_only/1 with two positive numbers.
%    true.
check(02) :-
    positive_numbers_only(1,1).

% Demonstrate basic usage of positive_numbers_only/1 with first number negative and second number positive.
% Result:
%    Both arguments must be positive numbers
%    false.
check(03) :-
    positive_numbers_only(-1,1).

% Demonstrate basic usage of positive_numbers_only/1 with first number positive and second number negative.
% Result:
%    Both arguments must be positive numbers
%    false.
check(04) :-
    positive_numbers_only(1,-1).

% Demonstrate basic usage of positive_numbers_only/1 with both numbers negative.
% Result:
%    Both arguments must be positive numbers
%    false.
check(05) :-
    positive_numbers_only(-1,-1).

% Demonstrate a wrapper that does nothing.
% Result:
%    Sum of -4 and -2 is -6
%    true.
check(06) :-
    wrap_predicate(add(X,Y,Sum),do_nothing,Original_goal,Original_goal),
    X = -4,
    Y = -2,
    add(X,Y,Sum),
    format('Sum of ~d and ~d is ~d~n',[X,Y,Sum]),
    unwrap_predicate(add/3,do_nothing).

% Demonstrate a wrapper that uses positive_numbers_only/2 as a condition before calling original add/3 goal.
% Result:
%    Sum of 2 and 1 is 3
%    true.
check(07) :-
    Body =
    (
        positive_numbers_only(X,Y)
    ->
        Original_goal
    ;
        false
    ),
    wrap_predicate(add(X,Y,Sum),wrap_example_01,Original_goal,Body),
    X = 2,
    Y = 1,
    (
        add(X,Y,Sum)
    ->
        format('Sum of ~d and ~d is ~d~n',[X,Y,Sum])
    ;
        true
    ),
    unwrap_predicate(add/3,wrap_example_01).

% Demonstrate a wrapper that uses positive_numbers_only/2 as a condition before calling original add/3 goal.
% Result:
%    Both arguments must be positive numbers
%    false.
check(08) :-
    Body =
    (
        positive_numbers_only(X,Y)
    ->
        Original_goal
    ;
        false
    ),
    wrap_predicate(add(X,Y,Sum),wrap_example_02,Original_goal,Body),
    X = -4,
    Y = -2,
    (
        add(X,Y,Sum)
    ->
        format('Sum of ~d and ~d is ~d~n',[X,Y,Sum])
    ;
        true
    ),
    unwrap_predicate(add/3,wrap_example_02).

% ----------------------------------------------------------------------------

add(X,Y,Sum) :-
    Sum is X + Y.

positive_numbers_only(X,Y) :-
    (
        X > 0,
        Y > 0
    ->
        true
    ;
        format('Both arguments must be positive numbers~n',[]),
        false
    ).

Exmaple run

Welcome to SWI-Prolog (threaded, 64 bits, version 9.1.6)
...

?- working_directory(_,'C:/Users/Groot').
true.

?- ['some_module'].
true.

?- check(1).
Sum of -1 and -5 is -6
true.

?- check(2).
true.

?- check(3).
Both arguments must be positive numbers
false.

?- check(4).
Both arguments must be positive numbers
false.

?- check(5).
Both arguments must be positive numbers
false.

?- check(6).
Sum of -4 and -2 is -6
true.

?- check(7).
Sum of 2 and 1 is 3
true.

?- check(8).
Both arguments must be positive numbers
false.

EDIT

For me, personally, it seems like creating a prompt for ChatGPT that correctly uses the Wrapped closure with wrap_predicate/4 takes more effort than simply coding it by hand. I find it difficult to explain the concept to ChatGPT in a way that it understands. However, I have noticed that many advanced concepts of Prolog can be just as challenging to convey to ChatGPT, making it faster to manually write the code.

1 Like